#
# exclude jobs prior to a designated job from a DAX process graph
#
# 
#

exjob=$1

a1=`mktemp /tmp/awk1.XXXXXX`

cat <<EOF >$a1

/<adag / {
	print \$0;
}

/<job / {
	id = \$2;
	sub( /^.*ID/,"ID",id);
	sub( /"/,"",id);
}

/<job /,/job>/ {
	job = job \$0 "\n";
}

/job>/ {
	jobtext[id] = job;
	job = "";
}

/<child ref=/ {
	child = \$2;
	sub( /^.*ID/,"ID",child);
	sub( /".*/,"",child);
	parents = "";
}

/<parent ref=/ {
	parent = \$2;
	sub( /^.*ID/,"ID",parent);
	sub( /".*/,"",parent);
	parents = parents " " parent;
}

/<\\/child>/ {
        sub("^  *","",parents);
	parlist[child] = parents;
#	print "DB: set parents of" child " to " parents;
}

function elim(node,plist) {
	delete jobtext[node];
	if ( ! (node in parlist) ) return;
	split(parlist[node], plist, " ")
	for ( p in plist ) {
		elim(plist[p]);
	}
	delete parlist[node];
}

END {
	j = jobtext["$exjob"];
	elim("$exjob");
	jobtext["$exjob"] = j;

	print("<!-- part 2: definition of remaining jobs -->");

	for (j in jobtext) {
		print(jobtext[j]);
	}
	print "<!-- part 3: list of control-flow dependencies (may be empty) -->";
	for ( c in parlist ) {
		printf("  <child ref=\"%s\">\n", c);
		split(parlist[c],plist," ");
		for(p in plist) {
			printf("    <parent ref=\"%s\"/>\n", plist[p]);
		}
		print("  </child>\n");
	}
	print "</adag>";
}

EOF

awk -f $a1 - 

rm $a1